home *** CD-ROM | disk | FTP | other *** search
/ FM Towns: Free Software Collection 4 / FM Towns Free Software Collection 4 - Disc 1.iso / oh_towns / townsfos / list.bas < prev    next >
BASIC Source File  |  1991-10-18  |  2KB  |  62 lines
  1. 10000 '
  2. 10010 ' List : File Listing Ulitity
  3. 10020 '
  4. 10030 ' Filename "LIST.BAS"
  5. 10040 '
  6. 10050 ' Last Update 1989. 5.19  Ver.1.01
  7. 10060 '
  8. 10070 '
  9. 10080 DEFINT A-Z
  10. 10090 NFLG=0
  11. 10100 PFLG=0
  12. 10110 LN=1
  13. 10120 '
  14. 10130 IF ARGC>1 THEN *PARA
  15. 10140 PRINT:PRINT "***** List : File Listing Utility : Ver.1.01 *****"
  16. 10150 PRINT
  17. 10160 LINE INPUT "    Filename ? ",FL$
  18. 10170   IF FL$="" THEN *END_EXIT
  19. 10180 GOTO *MAIN
  20. 10190 '
  21. 10200 *PARA
  22. 10210 FOR I=1 TO ARGC-1 : A$=ARGV$(I)
  23. 10220   IF A$="?" THEN *HELP
  24. 10230   IF A$="-p" OR A$="-P" THEN PFLG=-1:GOTO *SK_1
  25. 10240   IF A$="-n" OR A$="-N" THEN NFLG=-1:GOTO *SK_1
  26. 10250   IF FL$="" THEN FL$=A$:GOTO *SK_1
  27. 10260   GOTO *PARA_ERR
  28. 10270 *SK_1
  29. 10280 NEXT
  30. 10290 GOTO *MAIN
  31. 10300 '
  32. 10310 *HELP
  33. 10320 S_A$="\n***** Help Message for List : Ver.1.01 *****\n\n":                  GOSUB *S_PUTS_E
  34. 10330 S_A$="    List : File Listing Utility\n":GOSUB *S_PUTS_E
  35. 10340 S_A$="    Usage : List Filename [-p] [-n]\n":GOSUB *S_PUTS_E
  36. 10350 S_A$="    Option : -p Printer\n":GOSUB *S_PUTS_E
  37. 10360 S_A$="           : -n Line Number\n":GOSUB *S_PUTS_E
  38. 10370 GOTO *END_EXIT
  39. 10380 '
  40. 10390 *PARA_ERR
  41. 10400 S_A$="@ Parameter Error!\n":GOSUB *S_PUTS_E
  42. 10410 '
  43. 10420 *END_EXIT
  44. 10430 IF ARGC=0 THEN END
  45. 10440 RETURN *S_T_RETURN
  46. 10450 '
  47. 10460 ' MAIN
  48. 10470 '
  49. 10480 *MAIN
  50. 10490 IF PFLG THEN OPEN "O",#1,"LPT0:" ELSE OPEN "O",#1,"SCRN:"
  51. 10500 OPEN "I",#2,FL$
  52. 10510 '
  53. 10520 *LOOP
  54. 10530   LINE INPUT #2,A$
  55. 10540   IF NFLG THEN A$=RIGHT$("0000"+MID$(STR$(LN),2),5)+":"+A$:LN=LN+1
  56. 10550   PRINT #1,A$
  57. 10560   IF EOF(2) THEN *LOOP_EXIT
  58. 10570 GOTO *LOOP
  59. 10580 *LOOP_EXIT
  60. 10590 CLOSE
  61. 10600 GOTO *END_EXIT
  62.